build: allow enabling ASan on Windows with MSVC

ASan is supported with MSVC starting with Visual Studio 16.9, so we can
allow it if the right version is detected.

The syntax is different (each sanitiser should be provided as a separate
flag), and of the sanitisers that we support, only ASan is available in
MSVC. The new logic handles both of these MSVC-specific changes.

Author: iscgar

CMakeLists.txt

@@ -151,44 +151,52 @@ endif()
 
 if(ENABLE_SANITIZERS)
     if(NOT SANITIZERS)
-        set(SANITIZERS "address;undefined")
+        if(MSVC)
+            if(MSVC_VERSION LESS 1928)
+                # Technically 1928 is also used for VS 16.8, but CMake doesn't have a way
+                # to distinguish patch versions of MSVC, so this is good enough
+                message(FATAL_ERROR "Using sanitizers with MSVC requires Visual Studio 16.9 or newer")
+            endif()
+            set(SANITIZERS "address")
+        else()
+            set(SANITIZERS "address;undefined")
+        endif()
     endif()
 
-    if("thread" IN_LIST SANITIZERS)
-        list(REMOVE_ITEM SANITIZERS "thread")
-        list(APPEND SANITIZE_OPTIONS thread)
-    endif()
-    if("address" IN_LIST SANITIZERS)
-        list(REMOVE_ITEM SANITIZERS "address")
-        list(APPEND SANITIZE_OPTIONS address)
-    endif()
-    if("undefined" IN_LIST SANITIZERS)
-        list(REMOVE_ITEM SANITIZERS "undefined")
-        list(APPEND SANITIZE_OPTIONS alignment bounds)
-        list(APPEND SANITIZE_OPTIONS shift signed-integer-overflow integer-divide-by-zero)
-        list(APPEND SANITIZE_OPTIONS null bool enum)
-        list(APPEND SANITIZE_OPTIONS return)
-    endif()
-    if(SANITIZERS)
-        message(FATAL_ERROR "Unknown sanitizer(s) ${SANITIZERS}")
-    else()
-        message(STATUS "Using sanitizer options ${SANITIZE_OPTIONS}")
-    endif()
+    foreach(option ${SANITIZERS})
+        if(option STREQUAL "thread" AND NOT MSVC)
+            list(APPEND SANITIZE_OPTIONS thread)
+        elseif(option STREQUAL "address")
+            list(APPEND SANITIZE_OPTIONS address)
+        elseif(option STREQUAL "undefined" AND NOT MSVC)
+            list(APPEND SANITIZE_OPTIONS alignment bounds)
+            list(APPEND SANITIZE_OPTIONS shift signed-integer-overflow integer-divide-by-zero)
+            list(APPEND SANITIZE_OPTIONS null bool enum)
+            list(APPEND SANITIZE_OPTIONS return)
+        else()
+            message(FATAL_ERROR "Unknown sanitizer ${option}")
+        endif()
+    endforeach()
 
-    string(REPLACE ";" "," SANITIZE_OPTIONS "${SANITIZE_OPTIONS}")
+    message(STATUS "Using sanitizer options ${SANITIZE_OPTIONS}")
 
-    if (NOT APPLE)
-        set(SANITIZE_FLAGS "-O1 -fsanitize=${SANITIZE_OPTIONS} -fno-sanitize-recover=address,undefined")
+    if(MSVC)
+        string(REPLACE ";" " /fsanitize=" SANITIZE_OPTIONS "${SANITIZE_OPTIONS}")
+        set(SANITIZE_FLAGS "/Zi /fsanitize=${SANITIZE_OPTIONS}")
     else()
+        string(REPLACE ";" "," SANITIZE_OPTIONS "${SANITIZE_OPTIONS}")
         set(SANITIZE_FLAGS "-O1 -fsanitize=${SANITIZE_OPTIONS}")
+        if (NOT APPLE)
+            set(SANITIZE_FLAGS "${SANITIZE_FLAGS} -fno-sanitize-recover=address,undefined")
+        endif()
     endif()
 
     if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
         set(SANITIZE_FLAGS "${SANITIZE_FLAGS} -fno-omit-frame-pointer -fno-optimize-sibling-calls")
     elseif(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
         set(SANITIZE_FLAGS "${SANITIZE_FLAGS} -fuse-ld=gold")
-    else()
-        message(FATAL_ERROR "Sanitizers are only available when using GCC or Clang")
+    elseif(NOT MSVC)
+        message(FATAL_ERROR "Sanitizers are only available when using MSVC, GCC, or Clang")
     endif()
 
     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} ${SANITIZE_FLAGS}")