How to display in menu the packages coming from `packagesFrom`?

[zmrocze]

Hey!

I include a traditional devshell called other in my default devshell with devshells.default.devshell.packagesFrom = [ other ].

problem

The included other devshell provides i.e. the ghci command. But the command is not listed and documented in the menu that gets shown on entering the shell with:

motd = ''$(type -p menu &>/dev/null && menu)'';

How could I list it there as well?

tried solution

What I tried and how it didn't work is described in this issue of mine: #312 .

[phanirithvij]

You can use

Example

{
  pkgs ? import <nixpkgs> { },
  lib ? pkgs.lib,
}:
let
  mapCommands =
    category: packages:
    builtins.map (p: {
      inherit category;
      package = p;
    }) packages;

  # Returns a list of all the input derivation ... for a derivation.
  inputsOf =
    drv:
    lib.filter lib.isDerivation (
      (drv.buildInputs or [ ])
      ++ (drv.nativeBuildInputs or [ ])
      ++ (drv.propagatedBuildInputs or [ ])
      ++ (drv.propagatedNativeBuildInputs or [ ])
    );

  commandsFrom =
    category: shells: (mapCommands category (lib.foldl' (sum: drv: sum ++ (inputsOf drv)) [ ] shells));

  shell = pkgs.mkShell {
    packages = [
      pkgs.lf
      pkgs.lazygit
    ];
  };
in
commandsFrom "shell" [ shell ]

(some of the above functions are from numtide/devshell itself)