Add taint-tracking for sync package

Author: gagliardetto

ql/src/semmle/go/frameworks/Stdlib.qll

@@ -20,6 +20,7 @@ import semmle.go.frameworks.stdlib.PathFilepath
 import semmle.go.frameworks.stdlib.Reflect
 import semmle.go.frameworks.stdlib.Strconv
 import semmle.go.frameworks.stdlib.Strings
+import semmle.go.frameworks.stdlib.Sync
 import semmle.go.frameworks.stdlib.TextScanner
 import semmle.go.frameworks.stdlib.TextTabwriter
 import semmle.go.frameworks.stdlib.TextTemplate

ql/src/semmle/go/frameworks/stdlib/Sync.qll

@@ -0,0 +1,48 @@
+/**
+ * Provides classes modeling security-relevant aspects of the `sync` package.
+ */
+
+import go
+
+/** Provides models of commonly used functions in the `sync` package. */
+module Sync {
+  private class MethodModels extends TaintTracking::FunctionModel, Method {
+    FunctionInput inp;
+    FunctionOutput outp;
+
+    MethodModels() {
+      // signature: func (*Map).Load(key interface{}) (value interface{}, ok bool)
+      this.hasQualifiedName("sync", "Map", "Load") and
+      (inp.isReceiver() and outp.isResult(0))
+      or
+      // signature: func (*Map).LoadOrStore(key interface{}, value interface{}) (actual interface{}, loaded bool)
+      this.hasQualifiedName("sync", "Map", "LoadOrStore") and
+      (
+        inp.isReceiver() and outp.isResult(0)
+        or
+        inp.isParameter(_) and
+        (outp.isReceiver() or outp.isResult(0))
+      )
+      or
+      // signature: func (*Map).Range(f func(key interface{}, value interface{}) bool)
+      this.hasQualifiedName("sync", "Map", "Range") and
+      (inp.isReceiver() and outp.isParameter(0))
+      or
+      // signature: func (*Map).Store(key interface{}, value interface{})
+      this.hasQualifiedName("sync", "Map", "Store") and
+      (inp.isParameter(_) and outp.isReceiver())
+      or
+      // signature: func (*Pool).Get() interface{}
+      this.hasQualifiedName("sync", "Pool", "Get") and
+      (inp.isReceiver() and outp.isResult())
+      or
+      // signature: func (*Pool).Put(x interface{})
+      this.hasQualifiedName("sync", "Pool", "Put") and
+      (inp.isParameter(0) and outp.isReceiver())
+    }
+
+    override predicate hasTaintFlow(FunctionInput input, FunctionOutput output) {
+      input = inp and output = outp
+    }
+  }
+}