Introduce instruction type for component access

This is the union of a field-access and an element-access instruction

Author: smowton

ql/src/semmle/go/controlflow/IR.qll

@@ -253,23 +253,32 @@ module IR {
     )
   }
 
+  /**
+   * An IR instruction that reads a component from a composite object.
+   *
+   * This is either a field of a struct, or an element of an array, map, slice or string.
+   */
+  class ComponentReadInstruction extends ReadInstruction, EvalInstruction {
+    ComponentReadInstruction() {
+      e instanceof IndexExpr
+      or
+      e.(SelectorExpr).getBase() instanceof ValueExpr and
+      not e.(SelectorExpr).getSelector() = any(Method method).getAReference()
+    }
+
+    /** Gets the instruction computing the base value on which the field or element is read. */
+    Instruction getBase() { result = selectorBase(e) }
+  }
+
   /**
    * An IR instruction that reads the value of a field.
    *
    * On snapshots with incomplete type information, method expressions may sometimes be
    * misclassified as field reads.
    */
-  class FieldReadInstruction extends ReadInstruction, EvalInstruction {
+  class FieldReadInstruction extends ComponentReadInstruction {
     override SelectorExpr e;
 
-    FieldReadInstruction() {
-      e.getBase() instanceof ValueExpr and
-      not e.getSelector() = any(Method method).getAReference()
-    }
-
-    /** Gets the instruction computing the base value on which the field is read. */
-    Instruction getBase() { result = selectorBase(e) }
-
     /** Gets the field being read. */
     Field getField() { e.getSelector() = result.getAReference() }
 
@@ -299,12 +308,9 @@ module IR {
   /**
    * An IR instruction that reads an element of an array, slice, map or string.
    */
-  class ElementReadInstruction extends ReadInstruction, EvalInstruction {
+  class ElementReadInstruction extends ComponentReadInstruction {
     override IndexExpr e;
 
-    /** Gets the instruction computing the base value on which the element is looked up. */
-    Instruction getBase() { result = selectorBase(e) }
-
     /** Gets the instruction computing the index of the element being looked up. */
     Instruction getIndex() { result = evalExprInstruction(e.getIndex()) }
 

ql/src/semmle/go/dataflow/internal/DataFlowUtil.qll

@@ -593,30 +593,29 @@ class ReadNode extends InstructionNode {
 /**
  * A data-flow node that reads the value of a field from a struct, or an element from an array, slice, map or string.
  */
-abstract class ReadFromAggregateNode extends ReadNode {
+class ComponentReadNode extends ReadNode {
+  override IR::ComponentReadInstruction insn;
+
   /** Gets the data-flow node representing the base from which the field or element is read. */
-  abstract Node getBase();
+  Node getBase() { result = instructionNode(insn.getBase()) }
 }
 
 /**
- * Gets the data-flow node representing the bottom of a stack of zero or more `ReadFromAggregateNode`s.
+ * Gets the data-flow node representing the bottom of a stack of zero or more `ComponentReadNode`s.
  *
  * For example, in the expression a.b[c].d[e], this would return the dataflow node for the read from `a`.
  */
 Node getUnderlyingNode(ReadNode read) {
-  (result = read or result = read.(ReadFromAggregateNode).getBase+()) and
-  not result instanceof ReadFromAggregateNode
+  (result = read or result = read.(ComponentReadNode).getBase+()) and
+  not result instanceof ComponentReadNode
 }
 
 /**
  * A data-flow node that reads an element of an array, map, slice or string.
  */
-class ElementReadNode extends ReadFromAggregateNode {
+class ElementReadNode extends ComponentReadNode {
   override IR::ElementReadInstruction insn;
 
-  /** Gets the data-flow node representing the base from which the element is read. */
-  override Node getBase() { result = instructionNode(insn.getBase()) }
-
   /** Gets the data-flow node representing the index of the element being read. */
   Node getIndex() { result = instructionNode(insn.getIndex()) }
 
@@ -762,12 +761,9 @@ class AddressOperationNode extends UnaryOperationNode, ExprNode {
 /**
  * A data-flow node that reads the value of a field.
  */
-class FieldReadNode extends ReadFromAggregateNode {
+class FieldReadNode extends ComponentReadNode {
   override IR::FieldReadInstruction insn;
 
-  /** Gets the base node from which the field is read. */
-  override Node getBase() { result = instructionNode(insn.getBase()) }
-
   /** Gets the field this node reads. */
   Field getField() { result = insn.getField() }