Merge pull request #356 from max-schaefer/api-cleanup

Add and move around a few convenience predicates

Author: max-schaefer

ql/src/semmle/go/Decls.qll

@@ -112,14 +112,7 @@ class FuncDef extends @funcdef, StmtParent, ExprParent {
   DeferStmt getADeferStmt() { result.getEnclosingFunction() = this }
 
   /** Gets the `i`th result variable of this function. */
-  ResultVariable getResultVar(int i) {
-    result =
-      rank[i + 1](ResultVariable res, int j, int k |
-        res.getDeclaration() = getTypeExpr().getResultDecl(j).getNameExpr(k)
-      |
-        res order by j, k
-      )
-  }
+  ResultVariable getResultVar(int i) { result.isResultOf(this, i) }
 
   /** Gets a result variable of this function. */
   ResultVariable getAResultVar() { result.getFunction() = this }
@@ -131,9 +124,7 @@ class FuncDef extends @funcdef, StmtParent, ExprParent {
    */
   Parameter getParameter(int i) { result.isParameterOf(this, i) }
 
-  /**
-   * Gets a parameter of this function.
-   */
+  /** Gets a parameter of this function. */
   Parameter getAParameter() { result.getFunction() = this }
 
   /**

ql/src/semmle/go/Scopes.qll

@@ -274,12 +274,28 @@ class ReceiverVariable extends Parameter {
 
 /** A (named) function result variable. */
 class ResultVariable extends DeclaredVariable {
-  FuncDef fn;
+  FuncDef f;
+  int index;
 
-  ResultVariable() { fn.getTypeExpr().getAResultDecl().getNameExpr(_) = this.getDeclaration() }
+  ResultVariable() {
+    exists(FuncTypeExpr tp | tp = f.getTypeExpr() |
+      this =
+        rank[index + 1](DeclaredVariable parm, int j, int k |
+          parm.getDeclaration() = tp.getResultDecl(j).getNameExpr(k)
+        |
+          parm order by j, k
+        )
+    )
+  }
 
   /** Gets the function to which this result variable belongs. */
-  FuncDef getFunction() { result = fn }
+  FuncDef getFunction() { result = f }
+
+  /** Gets the index of this result among all results of the function. */
+  int getIndex() { result = index }
+
+  /** Holds if this is the `i`th result of function `fd`. */
+  predicate isResultOf(FuncDef fd, int i) { fd = f and i = index }
 }
 
 /**
@@ -396,13 +412,19 @@ class Function extends ValueEntity, @functionobject {
   Type getResultType(int i) { result = getType().(SignatureType).getResultType(i) }
 
   /** Gets the body of this function, if any. */
-  BlockStmt getBody() { none() }
+  BlockStmt getBody() { result = getFuncDecl().getBody() }
 
   /** Gets the `i`th parameter of this function. */
-  Parameter getParameter(int i) { none() }
+  Parameter getParameter(int i) { result.isParameterOf(getFuncDecl(), i) }
 
   /** Gets a parameter of this function. */
   Parameter getAParameter() { result = getParameter(_) }
+
+  /** Gets the `i`th reslt variable of this function. */
+  ResultVariable getResult(int i) { result.isResultOf(getFuncDecl(), i) }
+
+  /** Gets a result variable of this function. */
+  ResultVariable getAResult() { result = getResult(_) }
 }
 
 /**
@@ -512,10 +534,6 @@ class Method extends Function {
 class DeclaredFunction extends Function, DeclaredEntity, @declfunctionobject {
   override FuncDecl getFuncDecl() { result.getNameExpr() = this.getDeclaration() }
 
-  override BlockStmt getBody() { result = getFuncDecl().getBody() }
-
-  override Parameter getParameter(int i) { result = getFuncDecl().getParameter(i) }
-
   override predicate mayHaveSideEffects() {
     not exists(getBody())
     or

ql/src/semmle/go/dataflow/internal/DataFlowUtil.qll

@@ -236,9 +236,22 @@ abstract class FunctionNode extends Node {
   abstract ReceiverNode getReceiver();
 
   /**
-   * Gets a value returned by the given function via a return statement or an assignment to a result variable.
+   * Gets a value returned by the given function via a return statement or an assignment to a
+   * result variable.
    */
   abstract ResultNode getAResult();
+
+  /**
+   * Gets the data-flow node corresponding to the `i`th result of this function.
+   */
+  ResultNode getResult(int i) { result = getAResult() and result.getIndex() = i }
+
+  /**
+   * Gets the function entity this node corresponds to.
+   *
+   * Note that this predicate has no result for function literals.
+   */
+  Function getFunction() { none() }
 }
 
 /** A representation of a function that is declared in the module scope. */
@@ -251,8 +264,7 @@ class GlobalFunctionNode extends FunctionNode, MkGlobalFunctionNode {
 
   override string getName() { result = func.getName() }
 
-  /** Gets the function this node corresponds to. */
-  Function getFunction() { result = func }
+  override Function getFunction() { result = func }
 
   override ReceiverNode getReceiver() { result = receiverNode(func.(Method).getReceiver()) }
 
@@ -533,6 +545,9 @@ class ResultNode extends InstructionNode {
     or
     insn.(IR::ReadResultInstruction).reads(fd.getResultVar(i))
   }
+
+  /** Gets the index of this result among all results of the function. */
+  int getIndex() { result = i }
 }
 
 /**

ql/test/library-tests/semmle/go/Function/getParameter.expected

@@ -0,0 +1,11 @@
+| main.go:7:6:7:7 | f1 | 0 | main.go:7:9:7:9 | x |
+| main.go:9:12:9:13 | f2 | 0 | main.go:9:15:9:15 | x |
+| main.go:9:12:9:13 | f2 | 1 | main.go:9:18:9:18 | y |
+| main.go:9:12:9:13 | f2 | -1 | main.go:9:7:9:7 | t |
+| main.go:11:12:11:13 | f3 | 0 | main.go:11:15:11:15 | x |
+| main.go:11:12:11:13 | f3 | 1 | main.go:11:22:11:22 | y |
+| main.go:11:12:11:13 | f3 | -1 | main.go:11:7:11:7 | _ |
+| main.go:13:6:13:7 | f4 | 0 | main.go:13:9:13:9 | x |
+| main.go:13:6:13:7 | f4 | 1 | main.go:13:16:13:16 | y |
+| main.go:15:6:15:7 | f5 | 0 | main.go:15:9:15:9 | x |
+| main.go:17:6:17:7 | f6 | 0 | main.go:17:9:17:9 | x |

ql/test/library-tests/semmle/go/Function/getParameter.ql

@@ -0,0 +1,4 @@
+import go
+
+from Function f, int i
+select f, i, f.getParameter(i)

ql/test/library-tests/semmle/go/Function/getResult.expected

@@ -0,0 +1,7 @@
+| main.go:17:6:17:7 | f6 | 0 | main.go:17:17:17:17 | y |
+| main.go:19:6:19:7 | f7 | 0 | main.go:19:12:19:12 | x |
+| main.go:19:6:19:7 | f7 | 1 | main.go:19:15:19:15 | y |
+| main.go:21:6:21:7 | f8 | 0 | main.go:21:12:21:12 | x |
+| main.go:21:6:21:7 | f8 | 1 | main.go:21:19:21:19 | _ |
+| main.go:23:6:23:7 | f9 | 0 | main.go:23:12:23:12 | _ |
+| main.go:23:6:23:7 | f9 | 1 | main.go:23:19:23:19 | y |

ql/test/library-tests/semmle/go/Function/getResult.ql

@@ -0,0 +1,4 @@
+import go
+
+from Function f, int i
+select f, i, f.getResult(i)

ql/test/library-tests/semmle/go/Function/main.go

@@ -0,0 +1,23 @@
+package main
+
+type t int
+
+func main() {}
+
+func f1(x int) {}
+
+func (t t) f2(x, y int) {}
+
+func (_ t) f3(x int, y string) {}
+
+func f4(x int, y ...string) {}
+
+func f5(x int) int { return 0 }
+
+func f6(x int) (y int) { return 0 }
+
+func f7() (x, y int) { return 0, 0 }
+
+func f8() (x int, _ string) { return 0, "" }
+
+func f9() (_ int, y string) { return 0, "" }