fix: beam metadata not set when using custom capabilities (#744)

Author: jfpedroza

integration_test/chrome/capabilities_test.exs

@@ -149,5 +149,42 @@ defmodule Wallaby.Integration.CapabilitiesTest do
 
       assert :ok = Wallaby.end_session(session)
     end
+
+    test "adds the beam metadata when it is present" do
+      user_agent = "Mozilla/5.0"
+
+      defined_capabilities = %{
+        chromeOptions: %{args: ["--headless", "--user-agent=#{user_agent}"]}
+      }
+
+      expected_capabilities = %{
+        chromeOptions: %{
+          args: [
+            "--headless",
+            "--user-agent=#{user_agent}/BeamMetadata (g2gCZAACdjF0AAAAAW0AAAAEc29tZW0AAAAIbWV0YWRhdGE=)"
+          ]
+        }
+      }
+
+      Application.put_env(:wallaby, :chromedriver, capabilities: defined_capabilities)
+
+      create_session_fn = fn url, capabilities ->
+        assert capabilities == expected_capabilities
+
+        WebdriverClient.create_session(url, capabilities)
+      end
+
+      {:ok, session} =
+        SessionCase.start_test_session(
+          create_session_fn: create_session_fn,
+          metadata: %{"some" => "metadata"}
+        )
+
+      session
+      |> visit("page_1.html")
+      |> assert_has(Query.text("Page 1"))
+
+      assert :ok = Wallaby.end_session(session)
+    end
   end
 end

integration_test/selenium/selenium_capabilities_test.exs

@@ -63,5 +63,50 @@ defmodule Wallaby.Integration.SeleniumCapabilitiesTest do
 
       assert :ok = Wallaby.end_session(session)
     end
+
+    test "adds the beam metadata when it is present" do
+      user_agent = "Mozilla/5.0"
+
+      defined_capabilities = %{
+        browserName: "firefox",
+        "moz:firefoxOptions": %{
+          args: ["-headless"],
+          prefs: %{
+            "general.useragent.override" => user_agent
+          }
+        }
+      }
+
+      expected_capabilities = %{
+        browserName: "firefox",
+        "moz:firefoxOptions": %{
+          args: ["-headless"],
+          prefs: %{
+            "general.useragent.override" =>
+              "#{user_agent}/BeamMetadata (g2gCZAACdjF0AAAAAW0AAAAEc29tZW0AAAAIbWV0YWRhdGE=)"
+          }
+        }
+      }
+
+      Application.put_env(:wallaby, :selenium, capabilities: defined_capabilities)
+
+      create_session_fn = fn url, capabilities ->
+        assert capabilities == expected_capabilities
+
+        WebdriverClient.create_session(url, capabilities)
+      end
+
+      {:ok, session} =
+        SessionCase.start_test_session(
+          create_session_fn: create_session_fn,
+          metadata: %{"some" => "metadata"}
+        )
+
+      session
+      |> visit("page_1.html")
+      |> assert_has(Query.text("Page 1"))
+
+      assert :ok = Wallaby.end_session(session)
+    end
   end
 end

lib/wallaby/chrome.ex

@@ -337,7 +337,10 @@ defmodule Wallaby.Chrome do
     base_url = Chromedriver.base_url()
     create_session_fn = Keyword.get(opts, :create_session_fn, &WebdriverClient.create_session/2)
 
-    capabilities = Keyword.get(opts, :capabilities, capabilities_from_config(opts))
+    capabilities =
+      opts
+      |> Keyword.get_lazy(:capabilities, fn -> capabilities_from_config(opts) end)
+      |> put_beam_metadata(opts)
 
     with {:ok, response} <- create_session_fn.(base_url, capabilities) do
       id = response["sessionId"]
@@ -361,7 +364,7 @@ defmodule Wallaby.Chrome do
   defp capabilities_from_config(opts) do
     :wallaby
     |> Application.get_env(:chromedriver, [])
-    |> Keyword.get(:capabilities, default_capabilities(opts))
+    |> Keyword.get_lazy(:capabilities, &default_capabilities/0)
     |> put_headless_config(opts)
     |> put_binary_config(opts)
   end
@@ -543,13 +546,7 @@ defmodule Wallaby.Chrome do
   defdelegate log(session_or_element), to: WebdriverClient
 
   @doc false
-  def default_capabilities(opts \\ []) do
-    user_agent =
-      Metadata.append(
-        "Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/41.0.2228.0 Safari/537.36",
-        opts[:metadata]
-      )
-
+  def default_capabilities do
     chrome_options =
       maybe_put_chrome_executable(%{
         args: [
@@ -558,7 +555,7 @@ defmodule Wallaby.Chrome do
           "--disable-gpu",
           "--headless",
           "--fullscreen",
-          "--user-agent=#{user_agent}"
+          "--user-agent=Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/41.0.2228.0 Safari/537.36"
         ]
       })
 
@@ -609,6 +606,22 @@ defmodule Wallaby.Chrome do
     end)
   end
 
+  defp put_beam_metadata(capabilities, opts) do
+    capabilities
+    |> update_in([:chromeOptions, :args], fn args ->
+      for arg <- args do
+        case String.split(arg, "=") do
+          ["--user-agent", user_agent] ->
+            new_user_agent = Metadata.append(user_agent, opts[:metadata])
+            "--user-agent=#{new_user_agent}"
+
+          _ ->
+            arg
+        end
+      end
+    end)
+  end
+
   defp resolve_opt(opts, key) do
     case Keyword.fetch(opts, key) do
       {:ok, value} -> value

lib/wallaby/selenium.ex

@@ -103,7 +103,11 @@ defmodule Wallaby.Selenium do
   def start_session(opts \\ []) do
     base_url = Keyword.get(opts, :remote_url, remote_url_from_config())
     create_session = Keyword.get(opts, :create_session_fn, &WebdriverClient.create_session/2)
-    capabilities = Keyword.get(opts, :capabilities, capabilities_from_config(opts))
+
+    capabilities =
+      opts
+      |> Keyword.get_lazy(:capabilities, &capabilities_from_config/0)
+      |> put_beam_metadata(opts)
 
     with {:ok, response} <- create_session.(base_url, capabilities) do
       id = response["sessionId"]
@@ -123,10 +127,10 @@ defmodule Wallaby.Selenium do
     end
   end
 
-  defp capabilities_from_config(opts) do
+  defp capabilities_from_config do
     :wallaby
     |> Application.get_env(:selenium, [])
-    |> Keyword.get(:capabilities, default_capabilities(opts))
+    |> Keyword.get_lazy(:capabilities, &default_capabilities/0)
   end
 
   defp remote_url_from_config() do
@@ -352,19 +356,14 @@ defmodule Wallaby.Selenium do
   end
 
   @doc false
-  def default_capabilities(opts \\ []) do
-    user_agent =
-      Metadata.append(
-        "Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/41.0.2228.0 Safari/537.36",
-        opts[:metadata]
-      )
-
+  def default_capabilities do
     %{
       browserName: "firefox",
       "moz:firefoxOptions": %{
         args: ["-headless"],
         prefs: %{
-          "general.useragent.override" => user_agent
+          "general.useragent.override" =>
+            "Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/41.0.2228.0 Safari/537.36"
         }
       }
     }
@@ -429,4 +428,18 @@ defmodule Wallaby.Selenium do
       Map.fetch!(response, "value")
     end
   end
+
+  defp put_beam_metadata(%{"moz:firefoxOptions": %{prefs: %{}}} = capabilities, opts) do
+    capabilities
+    |> update_in(
+      [:"moz:firefoxOptions", :prefs, "general.useragent.override"],
+      fn user_agent ->
+        if user_agent do
+          Metadata.append(user_agent, opts[:metadata])
+        end
+      end
+    )
+  end
+
+  defp put_beam_metadata(capabilities, _opts), do: capabilities
 end