Ensure logger formatter works with chardata, closes #14921

Author: josevalim

lib/logger/lib/logger/formatter.ex

@@ -244,26 +244,38 @@ defmodule Logger.Formatter do
     case if(is_function(enabled, 0), do: enabled.(), else: enabled) do
       true ->
         color = md[:ansi_color] || Map.fetch!(colors, level)
-        fragment = IO.ANSI.format_fragment(color, true)
-        data = IO.iodata_to_binary(data)
-        size = byte_size(data)
+        [IO.ANSI.format_fragment(color, true), add_reset(data)]
 
-        cond do
-          :binary.at(data, size - 2) == ?\r and :binary.at(data, size - 1) == ?\n ->
-            [fragment, binary_part(data, 0, size - 2), IO.ANSI.reset() | "\r\n"]
+      false ->
+        data
+    end
+  end
 
-          :binary.at(data, size - 1) == ?\n ->
-            [fragment, binary_part(data, 0, size - 1), IO.ANSI.reset(), ?\n]
+  defp add_reset(binary) when is_binary(binary) do
+    size = byte_size(binary)
 
-          true ->
-            [fragment, data | IO.ANSI.reset()]
+    cond do
+      binary == "" ->
+        IO.ANSI.reset()
+
+      :binary.at(binary, size - 1) == ?\n ->
+        if size > 1 and :binary.at(binary, size - 2) == ?\r do
+          [binary_part(binary, 0, size - 2), IO.ANSI.reset() | "\r\n"]
+        else
+          [binary_part(binary, 0, size - 1), IO.ANSI.reset(), ?\n]
         end
 
-      false ->
-        data
+      true ->
+        [binary | IO.ANSI.reset()]
     end
   end
 
+  defp add_reset([?\r, ?\n]), do: [IO.ANSI.reset(), ?\r, ?\n]
+  defp add_reset([?\n]), do: [IO.ANSI.reset(), ?\n]
+  defp add_reset([last]), do: add_reset(last)
+  defp add_reset([h | t]), do: [h | add_reset(t)]
+  defp add_reset(rest), do: [rest | IO.ANSI.reset()]
+
   @doc """
   Formats the message of a log event.
   """

lib/logger/test/logger/formatter_test.exs

@@ -105,6 +105,14 @@ defmodule Logger.FormatterTest do
           colors: [enabled: true]
         )
 
+      assert %{level: :warning, msg: {:string, ""}, meta: %{}}
+             |> format(formatter)
+             |> IO.chardata_to_string() == "\e[33m\e[0m"
+
+      assert %{level: :warning, msg: {:string, "s"}, meta: %{}}
+             |> format(formatter)
+             |> IO.chardata_to_string() == "\e[33ms\e[0m"
+
       assert %{level: :warning, msg: {:string, "message"}, meta: %{}}
              |> format(formatter)
              |> IO.chardata_to_string() == "\e[33mmessage\e[0m"
@@ -116,6 +124,18 @@ defmodule Logger.FormatterTest do
       assert %{level: :warning, msg: {:string, "message\r\n"}, meta: %{}}
              |> format(formatter)
              |> IO.chardata_to_string() == "\e[33mmessage\e[0m\r\n"
+
+      assert %{level: :warning, msg: {:string, [?é, ["message", [?\n]]]}, meta: %{}}
+             |> format(formatter)
+             |> IO.chardata_to_string() == "\e[33mémessage\e[0m\n"
+
+      assert %{level: :warning, msg: {:string, [?é, "message", ?\r, ?\n]}, meta: %{}}
+             |> format(formatter)
+             |> IO.chardata_to_string() == "\e[33mémessage\e[0m\r\n"
+
+      assert %{level: :warning, msg: {:string, [?é, "message" | "\r\n"]}, meta: %{}}
+             |> format(formatter)
+             |> IO.chardata_to_string() == "\e[33mémessage\e[0m\r\n"
     end
   end