build.gradle

plugins {
    id "architectury-plugin" version "3.2-SNAPSHOT"
    id "dev.architectury.loom" version "0.7.2-SNAPSHOT" apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

     // Silences mojang mappings, if enabled. See dependencies block just below this.
     /*loom {
         silentMojangMappingsLicense()
     }*/

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"

        // The following line declares the mojmap mappings, you may use other mappings as well
        // mappings loom.officialMojangMappings()

        // The following line declares the yarn mappings you may select this one as well.
        mappings "net.fabricmc:yarn:${rootProject.yarn_version}:v2"
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.archives_base_name
    group = rootProject.maven_group

    if (System.env.CI == "true") {
        version = "${rootProject.mod_version}+a${System.env.GITHUB_RUN_NUMBER}.${System.env.GITHUB_REF.replaceAll("refs/heads/", "").replaceAll("/", "-")}"
    }
    else {
        version = "${rootProject.mod_version}+${rootProject.minecraft_version}"
    }

    repositories {
        maven {
            name = "Mod Menu Maven"
            url = "https://maven.terraformersmc.com/releases/"
        }
        /*maven {
            name = "Mod Menu Backup Maven"
            url = "https://raw.githubusercontent.com/TerraformersMC/Archive/main/releases/"
        }*/

        maven {
            name = "shedaniel Maven"
            url = "https://maven.shedaniel.me/"
        }

        maven {
            name = "Dodo Gang Maven Repo"
            url = "http://maven.dodogang.net/releases/"
            allowInsecureProtocol = true
        }
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"

        // The Minecraft launcher currently installs Java 8 for users, so your mod probably wants to target Java 8 too
        // JDK 9 introduced a new way of specifying this that will make sure no newer classes or methods are used.
        // We'll use that if it's available, but otherwise we'll use the older option.
        def targetVersion = 8
        if (JavaVersion.current().isJava9Compatible()) {
            options.release = targetVersion
        }
    }

    java {
        withSourcesJar()
    }
}