Add terraform skeleton

Author: russdaygh

terraform/api_server.tf

@@ -0,0 +1,27 @@
+resource "azurerm_service_plan" "api_server_service_plan" {
+  name                = "${local.resource_prefix}-api-server-serviceplan"
+  resource_group_name = azurerm_resource_group.rg.name
+  location            = azurerm_resource_group.rg.location
+  os_type             = "Linux"
+  sku_name            = "P0v3"
+}
+
+
+resource "azurerm_linux_web_app" "api_server_web_app" {
+  name                = "${local.resource_prefix}-api-server"
+  resource_group_name = azurerm_resource_group.rg.name
+  location            = azurerm_service_plan.api_server_service_plan.location
+  service_plan_id     = azurerm_service_plan.api_server_service_plan.id
+
+  site_config {
+    application_stack {
+      dotnet_version = "8.0"
+    }
+  }
+
+  connection_string {
+    name = "PocketDDDContext"
+    type = "SQLAzure"
+    value = local.db_connection_string
+  }
+}

terraform/blazor_client.tf

@@ -0,0 +1,5 @@
+resource "azurerm_static_web_app" "blazor-client" {
+  name                = "${local.resource_prefix}-blazorclient"
+  location            = "westeurope"
+  resource_group_name = azurerm_resource_group.rg.name
+}

terraform/database.tf

@@ -0,0 +1,26 @@
+resource "azurerm_mssql_server" "sqlserver" {
+  name                         = local.sql_server_name
+  resource_group_name          = azurerm_resource_group.rg.name
+  location                     = azurerm_resource_group.rg.location
+  version                      = "12.0"
+  administrator_login          = random_string.admin_login.result
+  administrator_login_password = random_password.admin_password.result
+
+  tags = {
+    environment = var.env
+  }
+}
+
+resource "azurerm_mssql_database" "sqldb" {
+  name      = "${local.resource_prefix}-sqldatabase"
+  server_id = azurerm_mssql_server.sqlserver.id
+
+  tags = {
+    environment = var.env
+  }
+
+  # prevent the possibility of accidental data loss
+  lifecycle {
+    prevent_destroy = true
+  }
+}

terraform/keyvault.tf

@@ -0,0 +1,38 @@
+data "azurerm_client_config" "current" {}
+
+resource "azurerm_key_vault" "key_vault" {
+  name                        = "${local.resource_prefix}-keyvault"
+  location                    = azurerm_resource_group.rg.location
+  resource_group_name         = azurerm_resource_group.rg.name
+  enabled_for_disk_encryption = true
+  tenant_id                   = data.azurerm_client_config.current.tenant_id
+  soft_delete_retention_days  = 7
+  purge_protection_enabled    = false
+
+  sku_name = "standard"
+
+  access_policy {
+    tenant_id = data.azurerm_client_config.current.tenant_id
+    object_id = data.azurerm_client_config.current.object_id
+
+    key_permissions = [
+      "Get",
+    ]
+
+    secret_permissions = [
+      "Get",
+      "Set",
+      "List"
+    ]
+
+    storage_permissions = [
+      "Get",
+    ]
+  }
+}
+
+resource "azurerm_key_vault_secret" "sqldb_connectionstring" {
+  name         = "${local.resource_prefix}-db-connection-string"
+  value        = local.db_connection_string
+  key_vault_id = azurerm_key_vault.key_vault.id
+}

terraform/locals.tf

@@ -0,0 +1,4 @@
+locals {
+  resource_prefix = "pocketddd-${var.env}"
+  sql_server_name = "${local.resource_prefix}-sql-server"
+}

terraform/main.tf

@@ -0,0 +1,18 @@
+resource "azurerm_resource_group" "rg" {
+  name     = "${local.resource_prefix}-rg"
+  location = "UK South"
+}
+
+resource "random_string" "admin_login" {
+  length           = 16
+  special          = true
+  override_special = "/@£$"
+}
+
+resource "random_password" "admin_password" {
+  length = 25
+}
+
+locals {
+  db_connection_string = "Server=tcp:${local.sql_server_name}.database.windows.net,1433;Persist Security Info=False;User ID=${random_string.admin_login.result};Password=${random_password.admin_password.result};MultipleActiveResultSets=False;Encrypt=True;TrustServerCertificate=False;Connection Timeout=30;"
+}

terraform/network.tf

@@ -0,0 +1,16 @@
+resource "azurerm_virtual_network" "vnet" {
+  name                = "${local.resource_prefix}-vnet"
+  location            = azurerm_resource_group.rg.location
+  resource_group_name = azurerm_resource_group.rg.name
+  address_space       = ["10.0.0.0/16"]
+  dns_servers         = ["10.0.0.4", "10.0.0.5"]
+
+  subnet {
+    name           = "subnet1"
+    address_prefix = "10.0.1.0/24"
+  }
+
+  tags = {
+    environment = var.env
+  }
+}

terraform/terraform.tf

@@ -0,0 +1,19 @@
+terraform {
+  required_providers {
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = "3.100.0"
+    }
+    random = {
+      source  = "hashicorp/random"
+      version = "3.6.1"
+    }
+  }
+}
+
+provider "azurerm" {
+  # Configuration options
+  features {
+
+  }
+}

terraform/variables.tf

@@ -0,0 +1,5 @@
+variable "env" {
+  default  = "dev"
+  nullable = false
+  type     = string
+}