Solve 2015 22

Author: code-shoily

lib/2015/day_22.ex

@@ -0,0 +1,128 @@
+defmodule AdventOfCode.Y2015.Day22 do
+  @moduledoc """
+  --- Day 22: Wizard Simulator 20XX ---
+  Problem Link: https://adventofcode.com/2015/day/22
+  Difficulty: m
+  Tags: dijkstra game-sim
+  """
+  alias AdventOfCode.Helpers.{InputReader, Transformers}
+  alias Yog.Traversal.Implicit
+
+  def input, do: InputReader.read_from_file(2015, 22)
+
+  def run(input \\ input()) do
+    boss = parse(input)
+    {solve(boss, :normal), solve(boss, :hard)}
+  end
+
+  def parse(input) do
+    lines = Transformers.lines(input)
+
+    %{
+      hp: lines |> Enum.at(0) |> String.split(": ") |> List.last() |> String.to_integer(),
+      dmg: lines |> Enum.at(1) |> String.split(": ") |> List.last() |> String.to_integer()
+    }
+  end
+
+  defp solve(boss, mode) do
+    initial_state = %{
+      hp: 50,
+      mana: 500,
+      boss_hp: boss.hp,
+      boss_dmg: boss.dmg,
+      spent: 0,
+      effects: %{shield: 0, poison: 0, recharge: 0},
+      mode: mode
+    }
+
+    Implicit.implicit_fold_by(
+      from: initial_state,
+      using: :best_first,
+      priority: fn state, _ -> state.spent end,
+      visited_by: fn state ->
+        {state.hp, state.mana, state.boss_hp, state.effects}
+      end,
+      successors_of: fn state ->
+        if state.hp <= 0 or state.boss_hp <= 0, do: [], else: get_successors(state)
+      end,
+      initial: nil,
+      with: fn _, state, _ ->
+        if state.boss_hp <= 0, do: {:halt, state.spent}, else: {:continue, nil}
+      end
+    )
+  end
+
+  @spells [
+    %{name: :missile, cost: 53, dmg: 4, heal: 0, effect: nil, duration: 0},
+    %{name: :drain, cost: 73, dmg: 2, heal: 2, effect: nil, duration: 0},
+    %{name: :shield, cost: 113, dmg: 0, heal: 0, effect: :shield, duration: 6},
+    %{name: :poison, cost: 173, dmg: 0, heal: 0, effect: :poison, duration: 6},
+    %{name: :recharge, cost: 229, dmg: 0, heal: 0, effect: :recharge, duration: 5}
+  ]
+
+  defp get_successors(state) do
+    # Player Turn Start
+    state = if state.mode == :hard, do: %{state | hp: state.hp - 1}, else: state
+
+    if state.hp <= 0 do
+      []
+    else
+      {state, _} = apply_effects(state)
+
+      if state.boss_hp <= 0 do
+        [%{state | boss_hp: 0}]
+      else
+        # Try casting each spell
+        for spell <- @spells,
+            state.mana >= spell.cost,
+            spell.effect == nil or Map.get(state.effects, spell.effect) <= 0 do
+          cast(state, spell)
+        end
+        |> Enum.map(fn state_after_cast ->
+          if state_after_cast.boss_hp <= 0 do
+            %{state_after_cast | boss_hp: 0}
+          else
+            # Boss Turn
+            {state_after_effects, armor} = apply_effects(state_after_cast)
+
+            if state_after_effects.boss_hp <= 0 do
+              %{state_after_effects | boss_hp: 0}
+            else
+              # Boss Attack
+              dmg = max(1, state_after_effects.boss_dmg - armor)
+              final_state = %{state_after_effects | hp: state_after_effects.hp - dmg}
+              if final_state.hp <= 0, do: nil, else: final_state
+            end
+          end
+        end)
+        |> Enum.reject(&is_nil/1)
+      end
+    end
+  end
+
+  defp apply_effects(state) do
+    %{shield: s, poison: p, recharge: r} = state.effects
+
+    boss_hp = if p > 0, do: state.boss_hp - 3, else: state.boss_hp
+    mana = if r > 0, do: state.mana + 101, else: state.mana
+    armor = if s > 0, do: 7, else: 0
+
+    new_effects = %{
+      shield: max(0, s - 1),
+      poison: max(0, p - 1),
+      recharge: max(0, r - 1)
+    }
+
+    {%{state | boss_hp: boss_hp, mana: mana, effects: new_effects}, armor}
+  end
+
+  defp cast(state, spell) do
+    state = %{state | mana: state.mana - spell.cost, spent: state.spent + spell.cost}
+
+    if spell.effect do
+      %{state | effects: Map.put(state.effects, spell.effect, spell.duration)}
+    else
+      %{state | boss_hp: state.boss_hp - spell.dmg, hp: state.hp + spell.heal}
+    end
+  end
+end

lib/2022/day_08.ex

@@ -74,9 +74,7 @@ defmodule AdventOfCode.Y2022.Day08 do
   end
 
   defp viewing_distance(grid, r, c, dr, dc, h) do
-    if not in_bounds?(grid, r, c) do
-      0
-    else
+    if in_bounds?(grid, r, c) do
       Implicit.implicit_fold(
         from: {r, c},
         using: :breadth_first,
@@ -91,6 +89,8 @@ defmodule AdventOfCode.Y2022.Day08 do
           {:continue, acc + 1}
         end
       )
+    else
+      0
     end
   end
 

lib/2022/day_10.ex

@@ -57,8 +57,6 @@ defmodule AdventOfCode.Y2022.Day10 do
           IO.write("▒")
         end
       end
-
-      IO.puts("")
     end
 
     :ok

priv/input_files/2015_22.txt

@@ -0,0 +1,2 @@
+Hit Points: 58
+Damage: 9

test/2015/day_22_test.exs

@@ -0,0 +1,12 @@
+defmodule AdventOfCode.Y2015.Day22Test do
+  @moduledoc false
+
+  use ExUnit.Case, async: true
+  @moduletag :y1522
+
+  alias AdventOfCode.Y2015.Day22, as: Solution
+
+  test "Year 2015, Day 22 run/1" do
+    assert Solution.run() == {1269, 1309}
+  end
+end