Solve 20_2_4

Author: code-shoily

lib/2024/day_02.ex

@@ -0,0 +1,53 @@
+defmodule AdventOfCode.Y2024.Day02 do
+  @moduledoc """
+  --- Day 2: Red-Nosed Reports ---
+  Problem Link: https://adventofcode.com/2024/day/2
+  Difficulty: s
+  Tags: sequence validation
+  """
+  alias AdventOfCode.Helpers.{InputReader, Transformers}
+
+  def input, do: InputReader.read_from_file(2024, 2)
+
+  def run(input \\ input()) do
+    reports = parse(input)
+
+    {run_1(reports), run_2(reports)}
+  end
+
+  defp run_1(reports) do
+    Enum.count(reports, &safe?/1)
+  end
+
+  defp run_2(reports) do
+    Enum.count(reports, fn report ->
+      safe?(report) or
+        0..(length(report) - 1)
+        |> Enum.any?(fn i ->
+          report |> List.delete_at(i) |> safe?()
+        end)
+    end)
+  end
+
+  defp safe?(report) do
+    diffs =
+      report
+      |> Enum.chunk_every(2, 1, :discard)
+      |> Enum.map(fn [a, b] -> b - a end)
+
+    all_increasing = Enum.all?(diffs, fn d -> d >= 1 and d <= 3 end)
+    all_decreasing = Enum.all?(diffs, fn d -> d <= -1 and d >= -3 end)
+
+    all_increasing or all_decreasing
+  end
+
+  def parse(data \\ input()) do
+    data
+    |> Transformers.lines()
+    |> Enum.map(fn line ->
+      line
+      |> String.split()
+      |> Enum.map(&String.to_integer/1)
+    end)
+  end
+end

lib/2024/day_04.ex

@@ -0,0 +1,67 @@
+defmodule AdventOfCode.Y2024.Day04 do
+  @moduledoc """
+  --- Day 4: Ceres Search ---
+  Problem Link: https://adventofcode.com/2024/day/4
+  Difficulty: s
+  Tags: grid word-search
+  """
+  alias AdventOfCode.Helpers.{InputReader, Transformers}
+
+  alias Yog.Builder.Grid
+
+  def input, do: InputReader.read_from_file(2024, 4)
+
+  def run(input \\ input()) do
+    grid = parse_to_map(input)
+
+    {run_1(grid), run_2(grid)}
+  end
+
+  defp run_1(grid) do
+    for {{x, y}, "X"} <- grid,
+        {dx, dy} <- Grid.queen(),
+        xmas?(grid, x, y, dx, dy),
+        reduce: 0 do
+      acc -> acc + 1
+    end
+  end
+
+  defp run_2(grid) do
+    for {{x, y}, "A"} <- grid,
+        x_mas?(grid, x, y),
+        reduce: 0 do
+      acc -> acc + 1
+    end
+  end
+
+  defp xmas?(grid, x, y, dx, dy) do
+    grid[{x + dx, y + dy}] == "M" and
+      grid[{x + 2 * dx, y + 2 * dy}] == "A" and
+      grid[{x + 3 * dx, y + 3 * dy}] == "S"
+  end
+
+  defp x_mas?(grid, x, y) do
+    d1 = {grid[{x - 1, y - 1}], grid[{x + 1, y + 1}]}
+    d2 = {grid[{x + 1, y - 1}], grid[{x - 1, y + 1}]}
+
+    valid_diag?(d1) and valid_diag?(d2)
+  end
+
+  defp valid_diag?({"M", "S"}), do: true
+  defp valid_diag?({"S", "M"}), do: true
+  defp valid_diag?(_), do: false
+
+  defp parse_to_map(data) do
+    lines = Transformers.lines(data)
+
+    for {line, y} <- Enum.with_index(lines),
+        {char, x} <- Enum.with_index(String.graphemes(line)),
+        into: %{} do
+      {{x, y}, char}
+    end
+  end
+
+  def parse(data \\ input()) do
+    data |> Transformers.lines()
+  end
+end