feat(http3): expose peername/sockname/peercert

Wires the three calls through to the underlying quic connection via
quic_h3:get_quic_conn/1 (available since quic 1.0.0). setopts still
returns {error, not_supported} since QUIC has no {active, once}-style
socket model.

Author: benoitc

NEWS.md

@@ -19,8 +19,10 @@ UNRELEASED
     `close/2`, `process/1`).
   - `hackney_qpack.erl` removed (~622 LOC); the QPACK codec lives in
     `quic_qpack` in the `quic` dependency.
-  - H3 peername/sockname/setopts/peercert now return `{error, not_supported}`:
-    the underlying `quic_h3` connection does not expose them.
+  - H3 `peername`/`sockname`/`peercert` are wired through the underlying
+    `quic` connection and work the same as for HTTP/1.1 and HTTP/2.
+    `setopts` still returns `{error, not_supported}` since QUIC has no
+    `{active, once}`-style socket model.
 - `rebar.config`: `quic` dependency pinned to hex `1.0.0`.
 
 3.2.1 - 2026-03-01

rebar.config

@@ -31,6 +31,10 @@
   {quic_h3, send_data, 4},
   {quic_h3, cancel, 3},
   {quic_h3, close, 1},
+  {quic_h3, get_quic_conn, 1},
+  {quic, peername, 1},
+  {quic, sockname, 1},
+  {quic, peercert, 1},
   %% hackney_h3 functions called by hackney_conn
   {hackney_h3, connect, 4},
   {hackney_h3, close, 2},
@@ -41,7 +45,10 @@
   {hackney_h3, send_data, 4},
   {hackney_h3, send_body_chunk, 4},
   {hackney_h3, finish_send_body, 3},
-  {hackney_h3, parse_response_headers, 1}
+  {hackney_h3, parse_response_headers, 1},
+  {hackney_h3, peername, 1},
+  {hackney_h3, sockname, 1},
+  {hackney_h3, peercert, 1}
 ]}.
 
 {cover_enabled, true}.

src/hackney_conn.erl

@@ -1509,19 +1509,19 @@ handle_common({call, From}, sockname, _State, #conn_data{transport = Transport,
     Result = Transport:sockname(Socket),
     {keep_state_and_data, [{reply, From, Result}]};
 
-%% HTTP/3 socket operations — peername/sockname/peercert/setopts not exposed
-%% by the underlying quic_h3 connection.
+%% HTTP/3 socket operations — peername/sockname/peercert delegated to the
+%% underlying quic connection; setopts has no analog over QUIC.
 handle_common({call, From}, peername, _State,
               #conn_data{h3_conn = H3Conn} = _Data) when H3Conn =/= undefined ->
-    {keep_state_and_data, [{reply, From, {error, not_supported}}]};
+    {keep_state_and_data, [{reply, From, hackney_h3:peername(H3Conn)}]};
 
 handle_common({call, From}, sockname, _State,
               #conn_data{h3_conn = H3Conn} = _Data) when H3Conn =/= undefined ->
-    {keep_state_and_data, [{reply, From, {error, not_supported}}]};
+    {keep_state_and_data, [{reply, From, hackney_h3:sockname(H3Conn)}]};
 
 handle_common({call, From}, peercert, _State,
               #conn_data{h3_conn = H3Conn} = _Data) when H3Conn =/= undefined ->
-    {keep_state_and_data, [{reply, From, {error, not_supported}}]};
+    {keep_state_and_data, [{reply, From, hackney_h3:peercert(H3Conn)}]};
 
 handle_common({call, From}, {setopts, _Opts}, _State,
               #conn_data{h3_conn = H3Conn} = _Data) when H3Conn =/= undefined ->

src/hackney_h3.erl

@@ -55,7 +55,10 @@
     reset_stream/3,
     handle_timeout/2,
     process/1,
-    get_fd/1
+    get_fd/1,
+    peername/1,
+    sockname/1,
+    peercert/1
 ]).
 
 %% gen_server callbacks
@@ -602,6 +605,25 @@ handle_timeout(_ConnRef, _NowMs) ->
 process(_ConnRef) ->
     infinity.
 
+-spec peername(reference()) ->
+    {ok, {inet:ip_address(), inet:port_number()}} | {error, term()}.
+peername(ConnRef) ->
+    quic_call(ConnRef, peername).
+
+-spec sockname(reference()) ->
+    {ok, {inet:ip_address(), inet:port_number()}} | {error, term()}.
+sockname(ConnRef) ->
+    quic_call(ConnRef, sockname).
+
+-spec peercert(reference()) -> {ok, binary()} | {error, term()}.
+peercert(ConnRef) ->
+    quic_call(ConnRef, peercert).
+
+quic_call(ConnRef, Op) ->
+    with_pid(ConnRef,
+             fun(Pid) -> gen_server:call(Pid, {quic_op, Op}) end,
+             {error, not_connected}).
+
 %%====================================================================
 %% gen_server callbacks
 %%====================================================================
@@ -640,6 +662,15 @@ handle_call({send_data, StreamId, Data, Fin}, _From, #state{h3_conn = Conn} = St
 handle_call({reset_stream, StreamId, ErrorCode}, _From, #state{h3_conn = Conn} = State) ->
     {reply, quic_h3:cancel(Conn, StreamId, ErrorCode), State};
 
+handle_call({quic_op, Op}, _From, #state{h3_conn = Conn} = State)
+  when Op =:= peername; Op =:= sockname; Op =:= peercert ->
+    Reply = try
+        quic:Op(quic_h3:get_quic_conn(Conn))
+    catch
+        _:Reason -> {error, Reason}
+    end,
+    {reply, Reply, State};
+
 handle_call(_Request, _From, State) ->
     {reply, {error, unknown_request}, State}.
 

test/hackney_conn_http3_tests.erl

@@ -38,7 +38,8 @@ http3_conn_test_() ->
             fun setup/0, fun cleanup/1,
             [
                 {"HTTP/3 connection and request", fun test_h3_connection_request/0},
-                {"HTTP/3 get_protocol returns http3", fun test_h3_get_protocol/0}
+                {"HTTP/3 get_protocol returns http3", fun test_h3_get_protocol/0},
+                {"HTTP/3 peername/sockname/peercert", fun test_h3_peer_info/0}
             ]
         }
     }.
@@ -115,6 +116,29 @@ test_h3_get_protocol() ->
             hackney_conn:stop(Pid)
     end.
 
+test_h3_peer_info() ->
+    {ok, Pid} = hackney_conn:start_link(#{
+        host => "cloudflare.com",
+        port => 443,
+        transport => hackney_ssl,
+        connect_options => [{protocols, [http3]}],
+        connect_timeout => 15000
+    }),
+    case hackney_conn:connect(Pid, 15000) of
+        ok ->
+            ?assertEqual(http3, hackney_conn:get_protocol(Pid)),
+            ?assertMatch({ok, {_, _}}, hackney_conn:peername(Pid)),
+            ?assertMatch({ok, {_, _}}, hackney_conn:sockname(Pid)),
+            case hackney_conn:peercert(Pid) of
+                {ok, Cert} -> ?assert(is_binary(Cert));
+                {error, no_peercert} -> ok
+            end,
+            hackney_conn:stop(Pid);
+        {error, Reason} ->
+            hackney_conn:stop(Pid),
+            ?debugFmt("H3 peer info test skipped: ~p", [Reason])
+    end.
+
 %%====================================================================
 %% hackney_h3 Module Tests
 %%====================================================================