Closed #76. Implemented and tested additional enumerating methods

Author: olekscode

src/DataFrame-Tests/DataFrameTest.class.st

@@ -1058,6 +1058,30 @@ DataFrameTest >> testInequality [
 	self assert: (df5 = df1) not.
 ]
 
+{ #category : #tests }
+DataFrameTest >> testInjectInto [
+	| numericDataFrame actual expected |
+	
+	numericDataFrame := DataFrame 
+		withRows: #(
+			(4.5 86 24)
+			(2.3 60 14)
+			(1.2 56 16)
+			(-1.0 12 18))
+		rowNames: #(A B C D)
+		columnNames: #(temperature humidity wind).
+
+	expected := DataSeries
+		withKeys: #(temperature humidity wind)
+		values: #(7.0 214 72)
+		name: '(no name)'.
+		
+	actual := numericDataFrame inject: 0 into:
+		[ :sum :each | sum + each ].
+	
+	self assert: actual equals: expected.
+]
+
 { #category : #tests }
 DataFrameTest >> testPrintOn [
 
@@ -1072,6 +1096,23 @@ DataFrameTest >> testPrintOn [
 	self assert: actual equals: expected.
 ]
 
+{ #category : #tests }
+DataFrameTest >> testReject [
+	| actual expected |
+
+	expected := DataFrame
+		withRows: #(
+			(Dubai 2.789 true)
+			(London 8.788 false))
+		rowNames: #(B C)
+		columnNames: df columnNames.
+		
+	actual := df reject:
+		[ :row | (row at: #Population) < 2 ].
+	
+	self assert: actual equals: expected.
+]
+
 { #category : #tests }
 DataFrameTest >> testRemoveColumn [
 
@@ -1423,6 +1464,23 @@ DataFrameTest >> testRowsPut [
 	self assert: dataFrame equals: expected.
 ]
 
+{ #category : #tests }
+DataFrameTest >> testSelect [
+	| actual expected |
+
+	expected := DataFrame
+		withRows: #(
+			(Dubai 2.789 true)
+			(London 8.788 false))
+		rowNames: #(B C)
+		columnNames: df columnNames.
+		
+	actual := df select:
+		[ :row | (row at: #Population) > 2 ].
+	
+	self assert: actual equals: expected.
+]
+
 { #category : #tests }
 DataFrameTest >> testSortBy [
 
@@ -1583,6 +1641,106 @@ DataFrameTest >> testVarSizeInstanceCreation [
 	self assert: dataFrame columnNames equals: #(1 2) asOrderedCollection.
 ]
 
+{ #category : #tests }
+DataFrameTest >> testWithIndexCollect [
+	| expectedDf expectedResult actualResult |
+	
+	expectedDf := DataFrame withRows: #(
+		(Barcelona 1.609 true)
+   		(Dubai 2.789 true)
+   		(London 8.788 false)).
+		
+	expectedDf rowNames: #(A B C).
+	expectedDf columnNames: #(City Population BeenThere).
+	
+	expectedResult := DataFrame withRows: #(
+		('BARCELONA' 2)
+   		('DUBAI' 4)
+   		('LONDON' 11)).
+		
+	expectedResult rowNames: #(A B C).
+	expectedResult columnNames: #(City Population).
+	
+	actualResult := df withIndexCollect: [ :row :index |
+		row at: #City put: (row at: #City) asUppercase.
+		row at: #Population put: (row at: #Population) asInteger + index.
+		row removeAt: #BeenThere.
+		row ].
+	
+	self assert: actualResult equals: expectedResult.
+	self assert: df equals: expectedDf.
+]
+
+{ #category : #tests }
+DataFrameTest >> testWithIndexDo [
+
+	| actual expected |
+
+	expected := { 
+		1 -> (DataSeries withKeys: df columnNames values: #(Barcelona 1.609 true) name: 'A') .
+		2 -> (DataSeries withKeys: df columnNames values: #(Dubai 2.789 true) name: 'B') .
+		3 -> (DataSeries withKeys: df columnNames values: #(London 8.788 false) name: 'C') } asDictionary.
+		
+	actual := Dictionary new.
+	
+	df withIndexDo: [ :each :index |
+		actual at: index put: each ].
+	
+	self assert: actual equals: expected.
+]
+
+{ #category : #tests }
+DataFrameTest >> testWithIndexDoCanModifyRows [
+	| expected |
+
+	expected := DataFrame
+		withRows: #(
+			(Barcelona 1.609 true)
+			(Dubai 4.789 true)
+			(London 11.788 false))
+		rowNames: df rowNames
+		columnNames: df columnNames.
+	
+	df withIndexDo: [ :row :index |
+		row name = 'A'
+			ifFalse: [ row at: #Population put: ((row at: #Population) + index) ] ].
+	
+	self assert: df equals: expected.
+]
+
+{ #category : #tests }
+DataFrameTest >> testWithIndexReject [
+	| actual expected |
+
+	expected := DataFrame
+		withRows: #(
+			(Barcelona 1.609 true)
+			(London 8.788 false))
+		rowNames: #(A C)
+		columnNames: df columnNames.
+		
+	actual := df withIndexReject: [ :row :index |
+		((row at: #Population) > 2) and: [ index % 2 = 0 ] ].
+	
+	self assert: actual equals: expected.
+]
+
+{ #category : #tests }
+DataFrameTest >> testWithIndexSelect [
+	| actual expected |
+
+	expected := DataFrame
+		withRows: #(
+			(Dubai 2.789 true))
+		rowNames: #(B)
+		columnNames: df columnNames.
+		
+	actual := df withIndexSelect: [ :row :index |
+		((row at: #Population) > 2) and: [ index % 2 = 0 ] ].
+	
+	self assert: actual equals: expected.
+]
+
 { #category : #tests }
 DataFrameTest >> testWithRowNameDo [
 

src/DataFrame/DataFrame.class.st

@@ -478,7 +478,7 @@ DataFrame >> closeTo: aDataFrame [
 
 { #category : #enumerating }
 DataFrame >> collect: aBlock [ 
-	"Overrides the Collection>>collect to create DataFrame with the same numer of columns as values in the first row"
+	"Overrides the Collection>>collect to create DataFrame with the same number of columns as values in the first row"
 	| firstRow newDataFrame |
 
 	firstRow := (self rowAt: 1) copy.
@@ -1175,6 +1175,61 @@ DataFrame >> variance [
 	^ self applyToAllColumns: #variance
 ]
 
+{ #category : #enumerating }
+DataFrame >> withIndexCollect: elementAndIndexBlock [
+	"Overrides withIndexCollect: to create DataFrame with the same number of columns as values in the first row"
+	| firstRow newDataFrame |
+	
+	firstRow := (self rowAt: 1) copy.
+	newDataFrame := self class new: 0@(elementAndIndexBlock value: firstRow value: 1) size.
+	newDataFrame columnNames: firstRow keys.
+	
+	self withIndexDo: [ :each :index | newDataFrame add: (elementAndIndexBlock value: each copy value: index)].
+	^ newDataFrame
+]
+
+{ #category : #enumerating }
+DataFrame >> withIndexDo: elementAndIndexBlock [
+
+	1 to: self size do: [ :i |
+		| row |
+		row := (self rowAt: i).
+		elementAndIndexBlock value: row value: i.
+			
+		"A hack to allow modification of rows inside do block"
+		self rowAt: i put: row asArray ].
+]
+
+{ #category : #enumerating }
+DataFrame >> withIndexReject: elementAndIndexBlock [ 
+	"Evaluate aBlock with each of the receiver's elements and index as the arguments. 
+	Collect into a new collection like the receiver, only those elements for 
+	which aBlock evaluates to false. Answer the new collection."
+	^ self withIndexSelect: [ :row :index | (elementAndIndexBlock value: row value: index) not ]
+]
+
+{ #category : #enumerating }
+DataFrame >> withIndexSelect: elementAndIndexBlock [ 
+	"Evaluate aBlock with each of the receiver's elements and index as the arguments. 
+	Collect into a new collection like the receiver, only those elements for 
+	which aBlock evaluates to true. Answer the new collection."
+
+	| rows selectedRowIndices selectedRowNames selectedRowsAsArrays df |
+	
+	rows := self asArrayOfRows.
+	selectedRowIndices := (1 to: rows size) select: [ :i |
+		elementAndIndexBlock value: (rows at: i) value: i ].
+	selectedRowNames := selectedRowIndices collect: [ :i | self rowNames at: i ].
+	selectedRowsAsArrays := selectedRowIndices collect: [ :i | (rows at: i) asArray ].
+	
+	df := self class
+		withRows: selectedRowsAsArrays
+		rowNames: selectedRowNames
+		columnNames: self columnNames.
+	
+	^ df
+]
+
 { #category : #enumerating }
 DataFrame >> withRowNameDo: elementAndKeyBlock [