Added DataFrame>> #toLatex

Author: Joshua-Dias-Barreto

src/DataFrame-Tests/DataFrameTest.class.st

@@ -5133,6 +5133,25 @@ DataFrameTest >> testToColumnsAtApplyElementwise [
 	self assert: df equals: expected
 ]
 
+{ #category : #tests }
+DataFrameTest >> testToLatex [
+
+	| expectedString |
+	expectedString := '\begin{tabular}{|l|l|l|l|}
+\hline
+\#  & City        & Population & BeenThere\\
+\hline
+''A'' & ''Barcelona'' & 1.609      & true     \\
+\hline
+''B'' & ''Dubai''     & 2.789      & true     \\
+\hline
+''C'' & ''London''    & 8.788      & false    \\
+\hline
+\end{tabular}'.
+
+	self assert: df toLatex equals: expectedString
+]
+
 { #category : #tests }
 DataFrameTest >> testToMarkdown [
 

src/DataFrame/DataFrame.class.st

@@ -2259,6 +2259,59 @@ DataFrame >> toColumnsAt: arrayOfColumnNumbers applyElementwise: aBlock [
 		self toColumnAt: each applyElementwise: aBlock ]
 ]
 
+{ #category : #converting }
+DataFrame >> toLatex [
+	" Prints the DataFrame as a Latex formatted table"
+
+	| markdown columnWidths dataFrame |
+	dataFrame := self copy.
+	dataFrame addColumn: dataFrame rowNames named: '\#' atPosition: 1.
+	markdown := WriteStream on: String new.
+	markdown nextPutAll: '\begin{tabular}{|'.
+	dataFrame numberOfColumns timesRepeat: [ markdown nextPutAll: 'l|' ].
+	markdown nextPutAll: '}'.
+	markdown cr.
+	markdown nextPutAll: '\hline'.
+	markdown cr.
+
+	columnWidths := dataFrame columnNames collect: [ :columnName |
+		                | maxWidth |
+		                maxWidth := columnName size.
+		                dataFrame rows do: [ :row |
+			                | value |
+			                value := row at: columnName.
+			                maxWidth := maxWidth max: value printString size ].
+		                maxWidth ].
+
+	dataFrame columnNames withIndexDo: [ :columnName :index |
+		| paddedColumnName |
+		paddedColumnName := columnName padRightTo: (columnWidths at: index).
+		index = dataFrame numberOfColumns
+			ifFalse: [ markdown nextPutAll: paddedColumnName , ' & ' ]
+			ifTrue: [ markdown nextPutAll: paddedColumnName ] ].
+	markdown nextPutAll: '\\'.
+	markdown cr.
+	markdown nextPutAll: '\hline'.
+	markdown cr.
+
+
+
+	dataFrame asArrayOfRows do: [ :row |
+		row withIndexDo: [ :value :index |
+			| paddedValue |
+			paddedValue := value printString padRightTo:
+				               (columnWidths at: index).
+			index = dataFrame numberOfColumns
+				ifFalse: [ markdown nextPutAll: paddedValue , ' & ' ]
+				ifTrue: [ markdown nextPutAll: paddedValue ] ].
+		markdown nextPutAll: '\\'.
+		markdown cr.
+		markdown nextPutAll: '\hline'.
+		markdown cr ].
+	markdown nextPutAll: '\end{tabular}'.
+	^ markdown contents
+]
+
 { #category : #converting }
 DataFrame >> toMarkdown [
 	" Prints the DataFrame as a Markdown formatted table"