Extend tests for queries with params and move them into a separe test suite

Author: amochin

test/tests/common_tests/basic_tests.robot

@@ -16,19 +16,6 @@ SQL Statement Ending With Semicolon Works
 SQL Statement Ending Without Semicolon Works
     Query    SELECT * FROM person;
 
-SQL Statement With Parameters Works
-    @{params}=    Create List    2
-    
-    IF  "${DB_MODULE}" in ["oracledb"]
-        ${output}=    Query    SELECT * FROM person WHERE id < :id    parameters=${params}
-    ELSE IF  "${DB_MODULE}" in ["sqlite3", "pyodbc"]
-        ${output}=    Query    SELECT * FROM person WHERE id < ?    parameters=${params}
-    ELSE
-        ${output}=    Query    SELECT * FROM person WHERE id < %s    parameters=${params}    
-    END
-    
-    Length Should Be    ${output}    1    
-
 Create Person Table
     [Setup]    Log    No setup for this test
     ${output}=    Create Person Table

test/tests/common_tests/query_params.robot

@@ -0,0 +1,67 @@
+*** Settings ***
+Documentation       Keywords with query params as seperate arguments work across all databases.
+
+Resource            ../../resources/common.resource
+
+Suite Setup         Connect To DB And Build Query
+Suite Teardown      Disconnect From Database
+Test Setup          Create Person Table And Insert Data
+Test Teardown       Drop Tables Person And Foobar
+
+
+*** Variables ***
+@{PARAMS}    Franz Allan
+
+
+*** Keywords ***
+Connect To DB And Build Query
+    Connect To DB
+    Build Query String With Params
+
+Build Query String With Params
+    ${sql}=    Set Variable    SELECT id FROM person WHERE FIRST_NAME=
+    IF  "${DB_MODULE}" in ["oracledb", "cx_Oracle"]
+        ${sql}=    Catenate    ${sql}    :id
+    ELSE IF  "${DB_MODULE}" in ["sqlite3", "pyodbc"]
+        ${sql}=    Catenate    ${sql}    ?
+    ELSE
+        ${sql}=    Catenate    ${sql}    %s
+    END
+    Set Suite Variable    ${QUERY}    ${sql}
+
+
+*** Test Cases ***
+Query
+    ${out}=    Query    ${QUERY}    parameters=${PARAMS}
+    Length Should Be    ${out}    1
+
+Row Count
+    ${out}=    Row Count    ${QUERY}    parameters=${PARAMS}
+    Should Be Equal As Strings    ${out}    1
+
+Description
+    ${out}=    Description    ${QUERY}    parameters=${PARAMS}
+    Length Should Be    ${out}    1
+
+Execute SQL String
+    Execute Sql String    ${QUERY}    parameters=${PARAMS}
+
+Check If Exists In DB
+    Check If Exists In Database    ${QUERY}    parameters=${PARAMS}
+
+Check If Not Exists In DB
+    @{Wrong params}=    Create List    Joe
+    Check If Not Exists In Database    ${QUERY}    parameters=${Wrong params}
+
+Row Count is 0
+    @{Wrong params}=    Create List    Joe
+    Row Count is 0    ${QUERY}    parameters=${Wrong params}
+
+Row Count is Equal to X
+    Row Count is Equal to X    ${QUERY}    1    parameters=${PARAMS}
+
+Row Count is Less Than X
+    Row Count is Less Than X    ${QUERY}    5    parameters=${PARAMS}
+
+Row Count is Greater Than X
+    Row Count is Greater Than X    ${QUERY}    0    parameters=${PARAMS}