move DSSP and STRIDE to extensions

Author: jgreener64

Project.toml

@@ -7,29 +7,31 @@ version = "3.1.0"
 BioGenerics = "47718e42-2ac5-11e9-14af-e5595289c2ea"
 BioSymbols = "3c28c6f8-a34d-59c4-9654-267d177fcfa9"
 CodecZlib = "944b1d66-785c-5afd-91f1-9de20f533193"
-DSSP_jll = "74334e00-59ce-546d-b517-81f3b7e1d491"
 Downloads = "f43a241f-c20a-4ad4-852c-f6b1247861c6"
 Format = "1fa38f19-a742-5d3f-a2b9-30dd87b9d5f8"
 LinearAlgebra = "37e2e46d-f89d-539d-b4ee-838fcccc9c8e"
 PrecompileTools = "aea7be01-6a6a-4083-8856-8a6e6704d82a"
 RecipesBase = "3cdcf5f2-1ef4-517c-9805-6587b60abb01"
-STRIDE_jll = "850473c1-9ef0-5df9-a957-757f4cde8b8b"
 Statistics = "10745b16-79ce-11e8-11f9-7d13ad32a3b2"
 
 [weakdeps]
 BioAlignments = "00701ae9-d1dc-5365-b64a-a3a3ebf5695e"
 BioSequences = "7e6ae17a-c86d-528c-b3b9-7f778a29fe59"
+DSSP_jll = "74334e00-59ce-546d-b517-81f3b7e1d491"
 DataFrames = "a93c6f00-e57d-5684-b7b6-d8193f3e46c0"
 Graphs = "86223c79-3864-5bf0-83f7-82e725a168b6"
 MMTF = "259c3a9c-12c3-507f-b21f-68ecc40fcda4"
 MetaGraphs = "626554b9-1ddb-594c-aa3c-2596fe9399a5"
+STRIDE_jll = "850473c1-9ef0-5df9-a957-757f4cde8b8b"
 
 [extensions]
 BioStructuresBioAlignmentsExt = ["BioSequences", "BioAlignments"]
 BioStructuresBioSequencesExt = "BioSequences"
+BioStructuresDSSPExt = "DSSP_jll"
 BioStructuresDataFramesExt = "DataFrames"
 BioStructuresGraphsExt = ["Graphs", "MetaGraphs"]
 BioStructuresMMTFExt = "MMTF"
+BioStructuresSTRIDEExt = "STRIDE_jll"
 
 [compat]
 BioAlignments = "3"

docs/src/api.md

@@ -10,6 +10,8 @@ Package extensions are used in order to reduce the number of dependencies:
 - To use `DataFrame`, call `using DataFrames`.
 - To use `MetaGraph`, call `using Graphs, MetaGraphs`.
 - To use [`MMTFDict`](@ref) or [`writemmtf`](@ref), call `import MMTF as MMTFPkg` (to avoid clashing with [`BioStructures.MMTF`](@ref)).
+- To use [`rundssp!`](@ref), [`rundssp`](@ref) or the `run_dssp` option for `read`/[`retrievepdb`](@ref), call `using DSSP_jll`.
+- To use [`runstride!`](@ref), [`runstride`](@ref) or the `run_stride` option for `read`/[`retrievepdb`](@ref), call `using STRIDE_jll`.
 
 Exported names:
 ```@index

ext/BioStructuresDSSPExt.jl

@@ -0,0 +1,58 @@
+module BioStructuresDSSPExt
+
+using BioStructures
+using DSSP_jll
+
+const dssp_executable = `$(DSSP_jll.mkdssp()) --mmcif-dictionary $(DSSP_jll.mmcif_pdbx_dic) --output-format dssp`
+
+function BioStructures.rundssp!(mo::Model)
+    # Write the structure to a temporary PDB file
+    # Our mmCIF writer does not write out enough of the required entries for DSSP to read it
+    tmp_pdb_path = tempname() * ".pdb"
+    open(tmp_pdb_path, "w") do io
+        println(io, "HEADER")
+        writepdb(io, mo)
+    end
+
+    # Run DSSP on the temporary PDB file
+    dssp_output_lines = readlines(pipeline(`$dssp_executable $tmp_pdb_path`))
+    rm(tmp_pdb_path)
+
+    data_begin = false
+    for line in dssp_output_lines
+        if startswith(line, "  #  RESIDUE AA STRUCTURE BP1")
+            data_begin = true
+            continue
+        end
+        data_begin || continue
+        line[14] == '!' && continue
+        res_id = strip(line[6:11]) # Insertion code is in column 11
+        ch_id = line[12]
+        ss_code = line[17]
+        ch = mo[ch_id]
+        # DSSP does not mark hetero atoms
+        if haskey(ch.residues, res_id)
+            sscode!(ch[res_id], ss_code)
+        elseif haskey(ch.residues, "H_$res_id")
+            sscode!(ch["H_$res_id"], ss_code)
+        else
+            error("Could not assign secondary structure to residue ID $res_id in chain $ch_id")
+        end
+    end
+    return mo
+end
+
+function BioStructures.rundssp!(struc::MolecularStructure)
+    for mo in values(models(struc))
+        rundssp!(mo)
+    end
+    return struc
+end
+
+BioStructures.rundssp(el::Union{MolecularStructure, Model}) = rundssp!(deepcopy(el))
+
+function BioStructures.rundssp(filepath_in, dssp_filepath_out)
+    run(`$dssp_executable $filepath_in $dssp_filepath_out`)
+end
+
+end # BioStructuresDSSPExt

ext/BioStructuresSTRIDEExt.jl

@@ -0,0 +1,44 @@
+module BioStructuresSTRIDEExt
+
+using BioStructures
+using STRIDE_jll
+
+const stride_executable = `$(STRIDE_jll.stride_exe())`
+
+function BioStructures.runstride!(mo::Model)
+    # Write the structure to a temporary PDB file
+    # STRIDE does not work with mmCIF files
+    tmp_pdb_path = tempname() * ".pdb"
+    open(tmp_pdb_path, "w") do io
+        writepdb(io, mo)
+    end
+
+    # Run STRIDE on the temporary PDB file
+    stride_output_lines = readlines(pipeline(`$stride_executable $tmp_pdb_path`))
+    rm(tmp_pdb_path)
+
+    for line in stride_output_lines
+        if startswith(line, "ASG")
+            ch_id = line[10]
+            res_id = strip(line[11:15]) # Insertion code is directly after residue number
+            ss_code = uppercase(line[25]) # STRIDE sometimes returns 'b' instead of 'B'
+            sscode!(mo[ch_id][res_id], ss_code)
+        end
+    end
+    return mo
+end
+
+function BioStructures.runstride!(struc::MolecularStructure)
+    for mo in values(models(struc))
+        runstride!(mo)
+    end
+    return struc
+end
+
+BioStructures.runstride(el::Union{MolecularStructure, Model}) = runstride!(deepcopy(el))
+
+function BioStructures.runstride(filepath_in, stride_filepath_out)
+    run(`$stride_executable $filepath_in -f$stride_filepath_out`)
+end
+
+end # BioStructuresSTRIDEExt

src/BioStructures.jl

@@ -16,14 +16,11 @@ using Downloads
 using Format
 using PrecompileTools
 using RecipesBase
-using STRIDE_jll
-using DSSP_jll
 
 using LinearAlgebra
 using Statistics
 
 include("model.jl")
-include("secondary.jl")
 include("select.jl")
 include("pdb.jl")
 include("mmcif.jl")

src/download.jl

@@ -373,7 +373,9 @@ Requires an internet connection.
 - `read_std_atoms::Bool=true`: whether to read standard ATOM records.
 - `read_het_atoms::Bool=true`: whether to read HETATOM records.
 - `run_dssp::Bool=false`: whether to run DSSP to assign secondary structure.
+    Requires the DSSP_jll.jl package to be imported if set to `true`.
 - `run_stride::Bool=false`: whether to run STRIDE to assign secondary structure.
+    Requires the STRIDE_jll.jl package to be imported if set to `true`.
 """
 function retrievepdb(pdbid::AbstractString;
             dir::AbstractString=pwd(),

src/model.jl

@@ -39,6 +39,8 @@ export
     defaultresname,
     defaultresidue,
     resnames,
+    sscode,
+    sscode!,
     chain,
     chainid,
     chainid!,
@@ -72,7 +74,14 @@ export
     pdbextension,
     generatechainid,
     MMTFDict,
-    writemmtf
+    writemmtf,
+    helixsscodes,
+    sheetsscodes,
+    coilsscodes,
+    rundssp!,
+    rundssp,
+    runstride!,
+    runstride
 
 "A macromolecular structural element."
 abstract type StructuralElement end
@@ -806,6 +815,39 @@ function DisorderedResidue(dis_res::DisorderedResidue, default::AbstractString)
     return DisorderedResidue(dis_res.names, default)
 end
 
+const ss_code_unassigned = '-'
+
+"""
+    sscode(res)
+    sscode(at)
+
+Get the secondary structure code of an `AbstractResidue` or `AbstractAtom` as a `Char`.
+
+`'$ss_code_unassigned'` represents unassigned secondary structure.
+Secondary structure can be assigned using `rundssp!` or `runstride!`.
+"""
+sscode(res::Residue) = res.ss_code
+sscode(dis_res::DisorderedResidue) = sscode(defaultresidue(dis_res))
+sscode(at::Atom) = sscode(residue(at))
+sscode(dis_at::DisorderedAtom) = sscode(defaultatom(dis_at))
+
+"""
+    sscode!(res, ss_code)
+
+Set the secondary structure code of an `AbstractResidue` to a `Char`.
+"""
+function sscode!(res::Residue, ss_code)
+    res.ss_code = ss_code
+    return res
+end
+
+function sscode!(dis_res::DisorderedResidue, ss_code)
+    for res_name in resnames(dis_res)
+        sscode!(disorderedres(dis_res, res_name), ss_code)
+    end
+    return dis_res
+end
+
 """
     chain(at)
     chain(res)
@@ -1643,6 +1685,8 @@ function generatechainid(entity_id::Integer)
     return out_string
 end
 
+# MMTF functions
+
 """
     MMTFDict(filepath; gzip=false)
     MMTFDict(io; gzip=false)
@@ -1680,6 +1724,66 @@ gzipped.
 """
 function writemmtf end
 
+# Secondary structure
+
+"`Set` of secondary structure codes corresponding to an α-helix."
+const helixsscodes = Set(['G', 'H', 'I', 'P'])
+
+"`Set` of secondary structure codes corresponding to a β-sheet."
+const sheetsscodes = Set(['E', 'B'])
+
+"`Set` of secondary structure codes corresponding to a coil."
+const coilsscodes = Set(['C', 'T', 'S', ' '])
+
+"""
+    rundssp!(struc)
+    rundssp!(model)
+
+Run DSSP (Define Secondary Structure of Proteins) on the given structural element
+to assign secondary structure.
+
+Requires the DSSP_jll.jl package to be imported.
+A temporary PDB file is written, so this will fail if the structural element cannot
+be written to a PDB file, for example if there are two-letter chain IDs.
+"""
+function rundssp! end
+
+"""
+    rundssp(struc)
+    rundssp(model)
+    rundssp(filepath_in, dssp_filepath_out)
+
+Return a copy of the structural element with DSSP (Define Secondary Structure of Proteins)
+run to assign secondary structure, or run DSSP directly on a PDB or mmCIF file.
+
+Requires the DSSP_jll.jl package to be imported.
+"""
+function rundssp end
+
+"""
+    runstride!(struc)
+    runstride!(model)
+
+Run STRIDE on the given structural element to assign secondary structure.
+
+Requires the STRIDE_jll.jl package to be imported.
+A temporary PDB file is written, so this will fail if the structural element cannot
+be written to a PDB file, for example if there are two-letter chain IDs.
+"""
+function runstride! end
+
+"""
+    runstride(struc)
+    runstride(model)
+    runstride(filepath_in, stride_filepath_out)
+
+Return a copy of the structural element with STRIDE
+run to assign secondary structure, or run STRIDE directly on a PDB file.
+
+Requires the STRIDE_jll.jl package to be imported.
+"""
+function runstride end
+
 # Descriptive showing of elements on a single line
 
 Base.show(io::IO, struc::MolecularStructure) = print(io,

src/pdb.jl

@@ -38,7 +38,9 @@ Read a Protein Data Bank (PDB) file and return a `MolecularStructure`.
 - `read_std_atoms::Bool=true`: whether to read standard ATOM records.
 - `read_het_atoms::Bool=true`: whether to read HETATOM records.
 - `run_dssp::Bool=false`: whether to run DSSP to assign secondary structure.
+    Requires the DSSP_jll.jl package to be imported if set to `true`.
 - `run_stride::Bool=false`: whether to run STRIDE to assign secondary structure.
+    Requires the STRIDE_jll.jl package to be imported if set to `true`.
 - `gzip::Bool=false`: whether the input is gzipped, not available for PDB
     format.
 """